subroutine uvrotp(u,v,uu,vv,id,jd,xpp,ypp,ihem)
      dimension u(id,jd),v(id,jd),uu(id,jd),vv(id,jd)
c
c Rotates winds to a true geographic sense from winds in a polar stereo
c grid sense.  Assumes data is on a polar stereo grid.
c
c input
c     u - input u components
c     v - input v components
c     id - i dimension of grid
c     jd - j dimension of grid
c     xpp - pole point in i direction
c     ypp - pole point in j direction
c     ihem - hemisphere of data where +1 is nh and -1 is sh.
c  note- The projection determines ihem
c        For projections down on north pole, set ihem=1.
c        For projections down on south pole, set ihem=-1.
c
c output
c     uu - rotated u wind (can be same array as input)
c     vv - rotated v wind (can be same array as input)
c
C XPP YPP  PARAMETERS FOR COMMON POLAR STEREO GRIDS
C
C       GRID                   XPP,YPP  XAX    IMX,JMX   IHEM
C       NMC 47X51               24,26    10     47,51      1
C       NMC 65X65  (NH)         33,33    10     65,65      1
C       NMC 65X65  (SH)         33,33    10     65,65     -1
C       NMC LFM (41X38 SET)     19,42   -15     41,38      1
C       NAVY 63X63              32,32    10     63,63      1
C       AUSTRALIAN 47X47        24,24     0     47,47     -1
C
c
c       note- values at pole assume longitude of +x axis of grid.
c
      xhem=1.
      if(ihem.eq.-1) xhem=-1.
      yr=xhem*xr
      do 20 j=1,jd
      do 20 i=1,id
      uz=i-xpp
      vz=j-ypp
      zz=sqrt(uz*uz+vz*vz)
      sn=0.
      cs=1.
      if(zz.le..00001) go to 12
      sn=vz/zz
      cs=uz/zz
   12 uh=-sn*u(i,j)+cs*v(i,j)
      vh=-cs*u(i,j)-sn*v(i,j)
      uu(i,j)=uh * xhem
      vv(i,j)=vh * xhem
   20 continue
      return
      end